Gmsh açık-kaynak camiasının önde gelen önişlem yazılımlarından biri olmasıyla Bilgisayar Destekli Mühendislik ihtiyaçlarının karşılanmasında çok önemli imkânlar sağlamaktadır ve ilâve olarak sonişlem yeteneğine de sahiptir.

Bu bölümde, muhtemel kullanıcıların sonlu elemanlar çözümlerinde ihtiyaç duyabilecekleri 2 Boyutlu cidar elemanlarından müteşekkil bir tam düzenli örgünün yarım küre yüzeyi için nasıl tanımlanıp imâl edileceğini gösteren kısa bir betik sunulacaktır.

Aşağıdaki betik kopyalanıp, örneğin "küre.geo" gibi adlandırılabilecek bir metin dosyasının içine yapıştırdıktan sonra Gmsh ile açarak rahatça kullanabilir, değiştirebilir ve tercih edilen çözücüye uygun bir biçimde ihraç edilebilir. Betiğin mevcut haliyle elde edilen sonuç hemen yukarıdaki resimde görüldüğü gibi olacaktır.

 ♦ gmsh:
// Kürevî kubbe için düzenli örgü
// http://alarga.uskudar.biz
 
r0 = 3.1125;  // yarıçap, m
ds = 23;      // her eğri üzerideki düğüm sayısı
 
alfa = 45;
r1 = r0*Cos(alfa*Pi/180);
z1 = r0*Sin(alfa*Pi/180);
Point (1) = {0, 0, 0};
Point (2) = {0, 0, z1};
Point (3) = {0, 0, r0};
Point (10) = {r0, 0, 0};
Point (11) = {-r0, 0, 0};
Point (12) = {0, r0, 0};
Point (13) = {0, -r0, 0};
  Circle (10) = {10, 1, 12};
  Circle (11) = {11, 1, 12};
  Circle (12) = {11, 1, 13};
  Circle (13) = {13, 1, 10};
Point (20) = {r1, 0, z1};
Point (21) = {-r1, 0, z1};
Point (22) = {0, r1, z1};
Point (23) = {0, -r1, z1};
  Circle (20) = {20, 1, 22};
  Circle (21) = {21, 1, 22};
  Circle (22) = {21, 1, 23};
  Circle (23) = {23, 1, 20};
  Circle (100) = {10,1,20};
  Circle (101) = {11,1,21};
  Circle (102) = {12,1,22};
  Circle (103) = {13,1,23};
Line Loop(200) = {100,-23,-103,13};
  Ruled Surface(200) = {200};
Line Loop(201) = {101,21,-102,-11};
  Ruled Surface(201) = {201};
Line Loop(202) = {102,-20,-100,10};
  Ruled Surface(202) = {202};
Line Loop(203) = {103,-22,-101,12};
  Ruled Surface(203) = {203};
Line Loop(204) = {20,-21,22,23};
  Ruled Surface(204) = {204};
Transfinite Line {10,11,12,13,20,21,22,23,100,101,102,103} = ds;
  Transfinite Surface "*";
  Recombine Surface "*";

Gmsh: küre.geo