Akış ayrılması hâdisesi, akışkan mekaniği temelli mühendislik çalışmalarında çok önemli bir inceleme sahasını oluşturmaktadır. Onlarca yıldır sürdürülmekte olan kapsamlı denel ve hesaplamalı incelemelere rağmen bu problem önemini sürdürmektedir. Hesaplamalı Akışkan Dinamiği (HAD) uygulamaları yakın dönemde iyice yaygınlaşmış olsa da henüz ağırlıklı olarak Reynolds Ortalamalı yöntemler kullanılmaktadır ki bu yaklaşımın yetersizlikleri aşikârdır, örneğin burada bahsi geçen türbülanslı sınır tabakanın ayrılması ve tekrar birleşmesi gibi durumların incelenmesi söz konusu olduğunda.

Bu alanda bir ilerleme elde edebilmek için kurgulanan "pürüzsüz iniş" olarak adlandırılabilecek bir kesit üzerinde yapılan yüksek çözünürlüklü rüzgâr tüneli ölçümlerini, Büyük Girdap Benzetimi (LES) temelli [Resim.1] hesaplamalı çözümlerle karşılaştırmaya yönelik olarak hazırlanan ve 2022'de yapılacak sunumlarla değerlendirilecek bir çalışma [2] vasıtasıyla konuyla ilgili bir miktar ilerleme sağlanması mümkün olabilir.

Burada bahsi geçen çalışma için kurgulanan geometri, gemi ve denizaltı kıçındaki karmaşık akış oluşumlarının basitleştirilmiş bir türevi olduğundan, incelenecek hesaplamalı yöntemler, gemi mühendisliği uygulamalarına yönelik katkılar açısından da son derece uygun veriler sağlayabileceği için bizim açımızdan da önemlidir.

Söz konusu kesit geometrisi hemen aşağıdaki beşinci derece polinom ile tanımlanmış bir eğriden ibarettir.

Konuyla ilgili bu ilk bölümde, söz konusu geometri için Gmsh adlı açık-kaynak önişlemci kullanılarak nasıl düzenli örgü oluşturulabileceği gösterilecektir. Böylece bu yazılım ile yeni tanışanlar için, bir fonksiyon ile tanımlanan geometrilerin makro kullanılarak nasıl kolayca çizilebileceği de öğretilmiş olacak ki aynı yaklaşımla mesela Naca kanat kesitlerinin veya Darpa Suboff geometrisinin de kolayca çizilebilmesi mümkün olabilir.

 ♦ gmsh:
// Yumuşak İniş kesiti için 2B tam düzenli hesaplama örgüsü
// Temel Veriler
L0 = 1.00;       // iniş eğrisinin uzunluğu, metre
H0 = 0.22*L0;    // eğrinin başlangıç seviyesinin yüksekliği
H1 = 0.5;        // kanal yüksekliği
Lg = 1.0*L0;     // giriş uzunluğu
Lc = 1.5*L0;     // çıkış uzunluğu
n  = 25;         // eğri üzerindeki nokta sayısı (değiştirmeye pek ihtiyaç yok)
px = 1.00;       // x yönünde düğüm noktalarının tek taraflı kademeli dağılımı için
py = 1.15;       // y yönünde düğüm noktalarının tek taraflı kademeli dağılımı için
dx = 45;         // x yönünde düğüm sayısı
dy = 25;         // y yönünde düğüm sayısı
 
// İniş eğrisi için makro başlangıcı
Macro Egri
      y =  H0 * (1 - (10 * (x/L0)^3) + (15 * (x/L0)^4) - (6 * (x/L0)^5));
Return
    For i In {0:n}
        x = L0/n *i;
        Call Egri;
        Point(i) = {x, y, 0.0};
        xx[i] = x;
        yy[i] = y;
   EndFor
// Makronun sonu
 
// Gerekli noktalar
Point(101) = {(L0+Lg), 0, 0};
Point(102) = {(-Lc), H0, 0};
Point(103) = {(-Lc), H0+H1, 0};
Point(104) = {0, H0+H1, 0};
Point(105) = {L0, H0+H1, 0};
Point(106) = {L0+Lg, H0+H1, 0};
 
// Tam Düzenli Örgü  
// Bölüm 1 - Giriş
Line(100) = {0,102};
Line(101) = {104,103};
Line(102) = {102,103};
Line(103) = {0,104};
      Transfinite Line(100) = dx Using Progression px;
      Transfinite Line(101) = dx Using Progression px;
      Transfinite Line(102) = dy Using Progression py;
      Transfinite Line(103) = dy Using Progression py;
        Line Loop(1) = {100,102,-101,-103};
        Plane Surface(1) = {1};
        Transfinite Surface(1) = {0,102,103,104};
        Recombine Surface(1);
 
// Bölüm 2 - İniş Eğrisi
Spline(1) = {0:n};
Line(104) = {104,105};
Line(105) = {25,105};
      Transfinite Line(1) = dx Using Progression px;
      Transfinite Line(104) = dx Using Progression px;
      Transfinite Line(103) = dy Using Progression py;
      Transfinite Line(105) = dy Using Progression py;
        Line Loop(2) = {-1, 103,104,-105};
        Plane Surface(2) = {2};
        Transfinite Surface(2) = {25,0,104,105};
        Recombine Surface(2);
 
// Bölüm 3 - Çıkış
Line(106) = {25,101};
Line(107) = {105,106};
Line(108) = {101,106};
      Transfinite Line(106) = dx Using Progression px;
      Transfinite Line(107) = dx Using Progression px;
      Transfinite Line(105) = dy Using Progression py;
      Transfinite Line(108) = dy Using Progression py;
        Line Loop(3) = {-106,105,107,-108};
        Plane Surface(3) = {3};
        Transfinite Surface(3) = {101,25,105,106};
        Recombine Surface(3);

Gmsh: inişEğrisi.geo

Görülebileceği gibi yukarıdaki gmsh betiğinde sadece iki boyutlu temel örgü oluşturulmuştur ve daha önce (eski sitede) verilen örnekler incelenerek kolayca üç boyutluya da dönüştürülebilir. Eğer fırsat olursa, tâkip edecek bölümlerde konunun OpenFOAM, SU2 ve Nektar++ ile incelenmesi düşünüldüğünden bu yazılımlara yönelik hazırlanmış, uygun sınır tabaka çözünürlüğüne sahip tam üç boyutlu hesaplama örgüleri için ihtiyaç duyulacak betikler de yeri geldikçe verilebilir.

Yine de bir masaüstü bilgisayar kullanarak, böylesine yüksek Reynolds sayılarında LES¹ çözümü elde edebilmek mümkün olmadığı için bizim yapacaklarımız RANS² sınırları içinde kalmak zorunda olacak, belki de biraz DES³...